The first question I asked myself when starting to write unit tests that involve files is: how do I upload files from my tests? Fortunately, dealing with files in Salesforce in a unit test context, is pretty easy.

Creating unit tests in Salesforce is a great way to ensure accurate data and maintain the integrity of Salesforce’s software applications. In this post, we’ll take a look at how to quickly and easily create text files in Salesforce to use them in your unit tests.

Straight to the point

Instantiate a ContentVersion with a name, description and a small content. In this case I will create a TXT file to keep it simple.

      
ContentVersion cv = new ContentVersion();
cv.Description  = 'test description';
cv.PathOnClient ='test_file.txt';
cv.Title = 'test file '+DateTime.now();
cv.versiondata=Blob.valueOf('test file body');
insert cv;
     
    

After creating the file we want to relate to one or many existing records such as an Account, Opportunity or even a custom object record.
To do that we have to insert a ContentDocumentLink

      
ContentDocumentLink cdl = new ContentDocumentLink();
cdl.ContentDocumentId = [SELECT Id, ContentDocumentId FROM ContentVersion WHERE Id =: cv.Id].ContentDocumentId;
cdl.LinkedEntityId ='ANY ID'; // <----- put your record id here, example: an account tid
cdl.ShareType = 'V';
insert cdl;

      
    

Now go to the associated record and see the file attachment. You will have to add the Files related list to the layout in case you don’t have it yet.

Photo by Christin Hume on Unsplash

When you’re developing applications in Salesforce, you may need to retrieve the name of a country based on its ISO code. If this is the case, let’s implement an Apex method that you can use to simplify the process.

The method is called getCountryNameByIsoCode and it takes a string argument that represents the ISO code for a particular country. For example, if you want to retrieve the name of the United States you would use the ISO code US.

The country ISO code for this method is from the standard alpha-2. Example: UY for Uruguay, AR for Argentina, etc

public static String getCountryNameByIsoCode(String isoCode){
    if(isoCode == null) return null;
    Schema.DescribeFieldResult fieldResult = User.Countrycode.getDescribe();
    List<Schema.PicklistEntry> pickListValues = fieldResult.getPicklistValues();
    
    for( Schema.PicklistEntry pickListEntry : pickListValues) {
        // pickListEntry.getLabel() returns the country name
        // pickListEntry.getValue() returns the country code
        if(pickListEntry.getValue().toLowerCase() == isoCode.toLowerCase()) {
            return pickListEntry.getLabel();
        }
    }
    return null;
}

Apex is a strongly typed, object-oriented programming language that allows developers to execute flow and transaction control statements on the Salesforce platform. It was developed by Salesforce and runs natively on their platform. Apex can be used to create custom business logic, automate processes and workflows, and integrate with external systems.

In short, Apex is a programming language for Salesforce that enables developers to build custom applications, automate business processes, and perform other tasks not possible with just point-and-click tools. It can be used to build custom triggers, classes, and interfaces to perform various functions on the Salesforce platform.

In Java, we can use Thread.sleep(1000) to delay the execution by one second. In Apex is not that easy since Salesforce is a multi-tenant environment. By Delaying the execution in the main thread we not only impact the users of our organization but also other Salesforce customers 🤯. That’s why we don’t have that sentence in Apex.

In a multi-tenancy environment, multiple customers share the same application, running on the same operating system, on the same hardware, and with the same data-storage mechanism. The distinction between the customers is achieved during application design, thus customers do not share or see each other’s data.

With some tricks, we can delay the execution without impacting our organization’s resources. Salesforce provides one mechanism to schedule an algorithm for one time or in a recurrent manner.

global class MyScheduler implements Schedulable {
    
    private final Id recordId;
    
    public MyScheduler(Id recordId){
        this.recordId = recordId;
    }
    
    global void execute(SchedulableContext sc){
        System.debug('**** recordId: '+this.recordId+'   date: '+Date.today());

        // ****** Do your logic here ******

        // abort to execute it only once
        System.abortJob(sc.getTriggerId()); 
    }
    
    public static void schedule(){
        String hour = String.valueOf(Datetime.now().hour());
        String min = String.valueOf(Datetime.now().minute() + 1); 
        String ss = String.valueOf(Datetime.now().second());
        
        //parse to cron expression
        String nextFireTime = ss + ' ' + min + ' ' + hour + ' * * ?';
        
        MyScheduler sc = new MyScheduler('0018F00000ABA3AQBX');
        
        String name = 'Submited at: '+String.valueOf(Datetime.now())+ ' next: '+nextFireTime;
        System.debug(name);

        System.schedule(name, nextFireTime, sc);
        
    }
}

How to use it

MyScheduler.schedule();

This is a common error when we start to work with testing or manipulating some particular objects: setup and non-setup objects. During test setup, we have to create some data to be used by the test because we don’t have access to the real org’s data unless we use the flag
SeeAllData=True which is not recommended.

Table of contents

• The error
• The solution
• The full example
• Resources

The error

Let’s say you want to create an Account and later a User. If you try to do it in the same transaction you will get this error (or similar):

System.DmlException: Insert failed. First exception on row 0; first error: MIXED_DML_OPERATION, DML operation on setup object is not permitted after you have updated a non-setup object (or vice versa): Account, original object: PermissionSetAssignment: []

Why?

The Salesforce documentation is pretty clear and basically, it says you cannot do a DML (insert or update) operation at the same time with objects that involve access-lever permissions

DML operations on certain sObjects, sometimes referred to as setup objects, can’t be mixed with DML on other sObjects in the same transaction. This restriction exists because some sObjects affect the user’s access to records in the org. You must insert or update these types of sObjects in a different transaction to prevent operations from happening with incorrect access-level permissions. For example, you can’t update an account and a user role in a single transaction.

The solution

Let’s see how to fix the MIXED_DML_OPERATION error

One option is to use @future method but since that’s for running in background, we cannot query that data in the next line due to it could be created or not.

Another solution is to insert setup objects such as User using the current user during the execution. We choose this one since we can access the user later in the test

      
System.runAs(new User(Id = UserInfo.getUserId())){ createUser(); }
   
    

The full example

      

  @isTest
  public class TestTest {

  @isTest static void itDoesNotWork() {
  createUser();
  createAccount();
  }

  @isTest static void itWorks() {
  System.runAs(new User(Id = UserInfo.getUserId())){ createUser(); }
  User user = [SELECT Id FROM User WHERE UserName LIKE 'admin%' LIMIT 1];
  createAccount();

  }

  private static void createAccount(){
  String random = String.valueof(DateTime.now().getTime());

  Account acc = new Account(Name = random);
  acc.CurrencyIsoCode = 'USD';
  acc.BillingCity = 'New York';
  acc.BillingCountry = 'United States';
  acc.BillingState = 'New York';
  acc.BillingStreet = 'abc 1234';
  acc.Website = 'www.google.com';

  insert ACC;

  }

  private static void createUser(){
  String random = String.valueof(DateTime.now().getTime());

  Profile profile = [SELECT Id FROM Profile WHERE Name='System Administrator'];

  User user = new User();
  user.Email = 'random@random.com'+random;
  user.UserName = 'admin@random.com'+random;
  user.LastName = 'random'+random;
  user.Alias = 'random';
  user.ProfileId = profile.Id;
  user.EmailEncodingKey='UTF-8';
  user.LanguageLocaleKey='en_US';
  user.LocaleSidKey='en_US';
  user.TimeZoneSidKey = 'America/Los_Angeles';

  insert user;
  }
  }

  
  

As you can see in the image below, the first test failed and the second one worked (the one running as current user)

Resources

• https://developer.salesforce.com/docs/atlas.en-us.apexcode.meta/apexcode/apex_dml_non_mix_sobjects.htm
• 
  https://developer.salesforce.com/docs/atlas.en-us.apexcode.meta/apexcode/apex_testing_seealldata_using.htm